.include "c:\0avr\8515def.inc"
.equ	vd0=$fe
.equ	vd1=$fd

.def	dly1	=r16
.def	dly2	=r17
.def	dly3	=r18
.def	rgn	=r21	;здесь намеренно используется один регистр
.def	st7	=r21	;для двух переменных

;следующий кусок актуален при использовании аппаратных прерываний 
;в этой программе используется только прерывание RESET
;для каждого типа микроконтроллеров AVR - свой набор прерываний, 
;в кодовом сегменте (.CSEG) памяти им соответствует строго определенное число строк,
;начиная с адреса 0 (.org 0)
;строки идут в строгой последовательности, в них должен стоять пустой оператор или
;имя метки, с которой начинается подпрограмма обработки прерывания
.CSEG
.org 0
	rjmp	RESET	; Reset Handler
	nop		; IRQ0 Handler	
	nop		; IRQ1 Handler
	nop		; Timer1 Capture Handler
	nop		; Timer1 CompareA Handler
	nop		; Timer1 CompareB Handler
	nop		; Timer1 Overflow Handler
	nop		; Timer0 Overflow Handler
	nop		; SPI Transfer Complete Handler
	nop		; UART RX Complete Handler
	nop		; UDR Empty Handler
	nop		; UART TX Complete Handler
	nop 		; Analog Comparator Handler

RESET:
;отключение WatchDog таймера:
	ldi	rgn,$18	
	out	WDTCR,rgn	
	ldi	rgn,$10
	out	WDTCR,rgn
	
;используешь подпрограмму - определи вершину стека!
	ldi	rgn,HIGH(RAMEND);начало стека
	out	SPH,rgn		;RAMEND, SPL, SPH для процессора AT90S8515 
	ldi	rgn,LOW(RAMEND)	;определено в файле 8515def.inc 
	out	SPL,rgn		;(см.1-ю строку программы)

;инициализация порта B: PORTB, DDRB, PINB определены в 8515def.inc	
	ser	rgn		;rgn=$ff
	out	PORTB,rgn	;на всех линиях - единица
	ldi	rgn,3		;3=0000 0011 в двоичном коде
	out	DDRB,rgn	;значит линии 7...2 - входные
				;       линии 1,0 - выходные
;к линиям 0 и 1 порта B подключим катоды светодиодов VD0 и VD1
;их аноды через резисторы 360...510 Ом подключим к цепи +5V
;линию 7 соединим через резистор 1кОм с +5V, 
;эту же линию соединим через выключенный тумблер с 0V
;следующий цикл будет продолжаться, пока при проверке линии 7 на ней не
;обнаружится низкий уровень, что произойдет после включения тумблера + 0...1 секунда
wt7st:	ldi	rgn,vd0			
	out	PORTB,rgn	;включение VD0,выключение VD1
	rcall	d05s		;на 0.5с
	ldi	rgn,vd1
	out	PORTB,rgn	;включение VD1,выключение VD0
	rcall	d05s		;на 0.5с
	in	st7,PINB	;считывание состояния линий порта B
	andi	st7,$80		;st7 & 1000 0000 (проверка линии 7)
	brne	wt7st

	ser	rgn		
	out	PORTB,rgn	;выключение светодиодов
end:	rjmp	end		;если на контакт RESET подать 0V - программа перезапустся


;===Подпрограмма задержки примерно на 0.5с при Fкварца=4МГц
d05s:	
;Следующая команда rjmp dend только для отладки, т.к.три вложенных цикла, идущих следом,
;при отладке в AVR Studio занимают очень много времени (всего $ff*$ff*$a=650250 повторов).
;При отладке можно проследить несколько шагов при заходе в подпрограмму задержки, 
;убрать точку с запятой перед командой rjmp dend и снова начать отладку;
;для рабочей программы перед этой командой поставить точку с запятой (;)
;	rjmp	dend		;пропуск всех циклов задержки

	ldi	dly3,$ff	;загрузка 3-х переменных циклов
d4ms:	ldi	dly2,$a		
wd2:	ldi	dly1,$ff
wdl:	dec	dly1
	brne	wdl
	dec	dly2
	brne	wd2	
	dec	dly3
	brne	d4ms	
dend:	ret			;последняя команда подпрограммы